plugins {
    id "com.android.application"
}

android {
    namespace "com.dsh.sync"
    compileSdk 34

    defaultConfig {
        applicationId "com.dsh.sync"
        minSdk 24
        targetSdk 34
        versionCode 1
        versionName "1.0.0"
    }

    signingConfigs {
        release {
            // Created by android/build.sh on first run. Without it Gradle falls
            // back to the debug key so a plain `gradle assembleRelease` still
            // produces an installable APK.
            def store = file("dsh-release.jks")
            if (store.exists()) {
                storeFile store
                storePassword "dshsync"
                keyAlias "dsh"
                keyPassword "dshsync"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            if (file("dsh-release.jks").exists()) {
                signingConfig signingConfigs.release
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    lint {
        abortOnError false
    }
}

dependencies {
    implementation "androidx.appcompat:appcompat:1.7.0"
    implementation "androidx.webkit:webkit:1.11.0"

    // appcompat pulls kotlin-stdlib 1.8.22 while a transitive androidx artifact
    // still drags the 1.6.x jdk7/jdk8 split modules, which duplicate its
    // classes. Align every kotlin-stdlib-* module on one version.
    constraints {
        implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk7:1.8.22") {
            because "duplicate classes against kotlin-stdlib 1.8.22"
        }
        implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.8.22") {
            because "duplicate classes against kotlin-stdlib 1.8.22"
        }
    }
}